---
title: "Evaluating Arguments using AND() & OR() | Airtable Support"
slug: "evaluate-arguments-using-and-and-or"
description: "This article covers how to evaluate arguments using AND() and OR() to streamline your team's and organization's work."
updated: 2025-07-23T21:28:44Z
published: 2025-07-23T21:28:44Z
---

> ## Documentation Index
> Fetch the complete documentation index at: https://support.airtable.com/llms.txt
> Use this file to discover all available pages before exploring further.

# Evaluating arguments using AND() and OR() in Airtable

Note

Consider having [Omni](https://support.airtable.com/docs/using-omni-ai-in-airtable) create an automation for you. With Omni's AI capabilities, you can use plain text requests to build, update, and query data in your Airtable base.

## AND() and OR() in Airtable overview

| Function | Behavior | Use Case | Structure |
| --- | --- | --- | --- |
| `AND()` | Returns “True” if all the arguments are true, returns “False” otherwise. | Using AND(), you can list any criteria to evaluate. If they are all "True," the function will return a "1" (true); otherwise, it will return a "0" (false). | `AND(logical 1, logical 2, logical 3, etc...)` |
| `OR()` | Returns “True” if any one of the arguments is true, returns “False” otherwise. | Using OR(), you can list any criteria to evaluate. If any of the values are "True," the function will return a "1" (true); otherwise, it will return a "0" (false). | `OR(logical 1, logical 2, logical 3, etc...)` |

## Using AND() in Airtable

**Using AND()**

AND() can be used on it's own as a standalone function, and it can also be used in conjunction with conditional statements.

As an example of using the function on it's own, let's write a formula to check if the following fields have a value in them:

- Status
- Project Owner
- Due Date

> Regardless of what function you're using, you can reference a field name to see if it has anything entered in it. For example, to check if a {Status} field has a value, you can just write: IF({Status}....
> 
> ```plaintext
> AND(
> {Status},
> {Project Owner},
> {Due Date}
> )
> ```
> 
> If all three fields have any value in them, the formula will return a 1, otherwise a 0.

![](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/image-1656575317052.png)

Notice that only the first record has a value of `1` because all three fields referenced in the formula have something entered in the field.

**Using AND() with conditional statements**

Taking the function a step further, let's see what it looks like to nest it within another statement. Using the same table structure, you have the following criteria:

- Projects that are assigned to Nathan
- And projects that are in progress
- Should show the message, "Nathan - Active"

Using AND(), here is the formula you would write:

```plaintext
IF(
   AND(
     {Project Owner} =  "Nathan Anderson", 
      Status = "In Progress"
   ),
   "Nathan - Active"
)
```

![1500000115581ANDOR002.jpg](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/1500000115581ANDOR002.jpg)

Let's change the criteria to look for the following:

- For projects that are not started
- And projects without a project owner
- Show a message, "Needs Owner"
- Otherwise, show "Next in Queue"

Here’s the formula:

```plaintext

IF (  
 AND (   
   {Status} = "Not Started" ,  
    {Project Owner}  
 ),    
  "Next in Queue" , 
  "Needs Owner" 
)
```

And here’s the result:

![1500000115561ANDOR003.jpg](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/1500000115561ANDOR003.jpg)

Let's build in some more complex conditions using AND()

- For projects that are not started
- And projects with a project owner
- Show a message, "Next in Queue"
- Otherwise, show "Needs Owner"
- And for projects in progress, show "Due Soon"
- Otherwise, for complete projects show "Complete"

Here’s the formula:

```plaintext
IF(
   AND(
      {Status} = "Not Started",
      {Project Owner}
   ),
      "Next in Queue",

IF(
   AND(
      {Status} = "Not Started",
      {Project Owner}=BLANK()
   ),
   "Needs Owner",

IF(
   AND(
      {Status} = "In Progress",
      {Due Date}
   ),
   "Due soon",
   "Complete"
)
)
)
```

And the result:

![360098989874ANDOR005](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/360098989874ANDOR005.jpg)

> [!CAUTION]
> Note
> 
> The formula above is not complete, as it doesn't account for all potential scenarios when some of the field values are empty. It's only meant to show a portion of the various AND() functions and their usage.

## Using OR() in Airtable

**Using OR()**

The OR() unction can also be used alone, or in combination with other functions.

Remember that when used by itself, OR()produces either a 1or 0 depending if *any* of the criteria listed in the statement are true. For example, OR (5+5=10, 5+5=12) will evaluate as 1 because one of the statements is true.

As an example, you want to display a message depending on the quantity of available items you have in stock. Let's start with the function by itself:

```plaintext
OR(
   {Status} = "Out of Stock", 
   {Status} = "Delayed Backorder"
)
```

![1500000115541ANDOR006](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/1500000115541ANDOR006.jpg)

Here’s the result:Using OR() with conditional statements

Building on the previous section, you may now want to display a message depending on if the result is a 1 or 0. You want to show "Available for purchase" if the item is in stock, or "Currently unavailable" if it is out of stock or on delayed backorder.

```plaintext
IF(
   OR(
      {Status} = "Out of Stock", 
      {Status} = "Phased Out"
   ),
   "Currently unavailable",
   "Available for purchase"   
)
```

Here is the example result for that formula:

![1500000115521ANDOR007.jpg](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/1500000115521ANDOR007.jpg)

## Combining AND() and OR() in Airtable

**Combining AND() and OR()**

Here’s an example of combining `AND() `and `OR() `together.

```plaintext
IF(
   Status = "In Stock",
      "Available for purchase",

IF(
   AND(
      Status = "Out of Stock",
      {Re-order}
   ),
      "Check back soon for availability",

IF(
   OR(
      Status = "Phased Out",
      Status = "Recalled"
   ),
      "No longer selling this product",
      "Unavailable for purchase"
)      
)
)
```

And here’s the result you can expect:

![360101209053ANDOR008.jpg](https://cdn.airtable.document360.io/d0ee2ee4-3f78-47c7-b388-85e40be9fb89/Images/Documentation/360101209053ANDOR008.jpg)