Formelfeldreferenz

01 Aug 2023
13 Minuten zu lesen

Drucken
Teilen
Dunkel
Hell
pdf

Formelfeldreferenz

Aktualisiert am 01 Aug 2023
13 Minuten zu lesen

Drucken
Teilen
Dunkel
Hell
pdf

Article Summary

Share feedback

Thanks for sharing your feedback!

Formeln können Funktionen, numerische Operationen, logische Operationen und Textoperationen in Feldern beinhalten. Einen Überblick über Formelfelder finden Sie im Leitfaden für Formel-, Lookup-, Anzahl- und Rollup-Felder.

Einführung

In einer Formel können Sie Felder (Spalten) nach Namen referenzieren. Um den Wert eines bestehenden Felds zurückzugeben, können Sie einfach den Namen des Feldes eingeben:

Price

Wenn Sie zum Beispiel eine Formel benötigen, die eine Gesamtsumme basierend auf Ihren Feldern für Preis und Menge berechnet, würde dies etwa so aussehen:

Price * Quantity

Feldnamen mit mehreren Wörtern müssen in geschweifte Klammern gesetzt werden:

MIN({Regular Price}, {Sale Price})

Formeln können diese Klammern ( ) enthalten, um die Reihenfolge der Operationen zu ändern:

(Apples + Oranges) / Guests

Ausdrücke

Ein Ausdruck wird erstellt, wenn Sie Werte, Felder oder Formeln kombinieren und diese Kombination zu einem einzigen Wert führt. Sie können einfache Ausdrücke erstellen wie z. B. unten gezeigt (die Formel unten würde einen einzigen Wert zurückgeben – sie ist daher ein Ausdruck):

{Sales Tax} * {Price}

Sie können Ausdrücke auch miteinander verketten. Dies ist vor allem bei logischen Operatoren hilfreich. Zum Beispiel ist IF(expression, value1, value2) das technische Muster für die Formel IF(). Denken wir das obige Beispiel einen Schritt weiter und nehmen an, wir möchten wissen, wann der Preis unseres Artikels über 100 liegt:

IF(   {Sales Tax} * {Price} > 100,   "This is over 100",   "This is less than 100" )

Der Ausdruck im obigen Block ist {Sales Tax} * {Price} > 100.

Ihre Ausdrücke können so kompliziert sein, wie Sie möchten – oder wie es nötig ist! Möchten Sie sich an Ausdrücken probieren und mehr darüber erfahren? Oder über Formeln im Allgemeinen?

Wir haben unten eine Formel-Experimentier-Base erstellt, in der Sie alle der Formeln referenzieren und testen können. Wie der Name der Base andeutet, haben wir diese Formel-Experimentier-Base erstellt, damit Sie die Formeln auf spielerische Art praktisch erlernen und ausprobieren können. Wir empfehlen, eine eigene Kopie der Formel-Experimentier-Base unten zu erstellen, damit Sie sie ganz einfach und bei Bedarf referenzieren können.

Letzte Aktualisierung: 21.09.2021

Wenn Sie diese Base zum ersten Mal öffnen, sehen Sie sich dieses kurze Demo-Video mit einer Übersicht zur Struktur dieser Base an.

Textoperatoren und -funktionen

Um die folgenden Textfunktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „✏️ Beispiele für Textfunktionen“ in der Formel-Experimentier-Base an.

Textoperatoren

Operator Beschreibung Beispiele

Operator	Beschreibung	Beispiele
`&`	Verketten Sie Textwerte zu einem einzigen Textwert. Um statischen Text zu verketten, setzen Sie ihn in doppelte Anführungszeichen. Um doppelte Anführungszeichen zu verketten, müssen Sie den Backslash (\) als Escapezeichen verwenden. Entspricht CONCATENATE().	`Name & " - " & Age` => Jane - 28 `"\""&{Product Name}&"\""` => "GreatProduct"

&

Verketten Sie Textwerte zu einem einzigen Textwert.

Um statischen Text zu verketten, setzen Sie ihn in doppelte Anführungszeichen. Um doppelte Anführungszeichen zu verketten, müssen Sie den Backslash (\) als Escapezeichen verwenden.

Entspricht CONCATENATE().

Name & " - " & Age

=> Jane - 28

"\""&{Product Name}&"\""

=> "GreatProduct"

Textfunktionen

Funktion	Beschreibung	Beispiele
`ARRAYJOIN([item1, item2, item3], separator)`	Verbindet ein Element-Array zu einer Zeichenfolge mit Trennzeichen.	`ARRAYJOIN(values, "; ")` => 1; 2; 3
`CONCATENATE(text1, [text2, ...])`	Verbindet Textargumente zu einem einzigen Textwert. Um statischen Text zu verketten, setzen Sie ihn in doppelte Anführungszeichen. Um doppelte Anführungszeichen zu verketten, müssen Sie den Backslash (\) als Escapezeichen verwenden. Entspricht der Verwendung des &-Operators.	`CONCATENATE("Bob"," - ", 43)` => Bob - 43 `CONCATENATE("\"",{Name},"\"")` => "Bob"
`ENCODE_URL_COMPONENT(component_string)`	Ersetzt bestimmte Zeichen mit codierten Äquivalenten zur Verwendung bei der Erstellung von URLs oder URIs. Codiert nicht die folgenden Zeichen: - _ . ~	`ENCODE_URL_COMPONENT("chicken & waffles")` => chicken%20%26%20waffles
`FIND(stringToFind, whereToSearch,[startFromPosition])`	Findet Vorkommen von stringToFind in der whereToSearch-Zeichenfolge beginnend mit optionalem startFromPosition. (startFromPosition ist standardmäßig 0.) Wenn kein stringToFind gefunden wird, ist das Ergebnis 0. Ähnlich wie SEARCH(), jedoch wird für SEARCH() statt 0 ein leeres Ergebnis zurückgegeben, wenn kein stringToFind gefunden wird.	`FIND("fox", "quick brown fox")` => 13
`LEFT(string, howMany)`	Extrahiert per howMany die Anzahl der Zeichen ab Beginn der Zeichenfolge.	`LEFT("quick brown fox", 5)` => quick
`LEN(string)`	Gibt die Länge einer Zeichenfolge zurück.	`LEN("quick brown fox")` => 15
`LOWER(string)`	Ändert eine Zeichenfolge in Kleinschreibung.	`LOWER("Hello!")` => hello!
`MID(string, whereToStart, count)`	Extrahiert eine Teilzeichenfolge für die Zeichenanzahl ab whereToStart.	`MID("quick brown fox", 6, 5)` => brown
`REPLACE(string, start_character, number_of_characters, replacement)`	Ersetzt die Anzahl der Zeichen beginnend mit dem Startzeichen mit dem ersetzenden Text. (Um zu erfahren, wie Sie alle Vorkommen von old_text durch new_text ersetzen, siehe SUBSTITUTE().)	`REPLACE("database", 2, 5, "o")` => dose
`REPT(string, number)`	Wiederholt eine Zeichenfolge um die angegebene Anzahl.	`REPT("Hi! ", 3)` => Hi! Hi! Hi!
`RIGHT(string, howMany)`	Extrahiert per howMany die Anzahl der Zeichen ab Ende der Zeichenfolge.	`RIGHT("quick brown fox", 5)` => n fox
`SEARCH(stringToFind, whereToSearch,[startFromPosition])`	Sucht nach Vorkommen von stringToFind in der whereToSearch-Zeichenfolge beginnend mit optionalem startFromPosition. (startFromPosition ist standardmäßig 0.) Wenn kein stringToFind gefunden wird, ist das Ergebnis leer. Ähnlich wie FIND(), jedoch wird für FIND() statt eines leeren Ergebnisses 0 zurückgegeben, wenn kein stringToFind gefunden wird.	`SEARCH("World", "Hello World")` => 7
`SUBSTITUTE(string, old_text, new_text, [index])`	Ersetzt Vorkommen von old_text durch new_text. Sie können optional eine Indexnummer (beginnend bei 1) angeben, um nur ein bestimmtes Vorkommen von old_text zu ersetzen. Wenn keine Indexnummer angegeben wird, werden alle Vorkommen von old_text ersetzt. (Um zu erfahren, wie Sie stattdessen Zeichen in einer Zeichenfolge ab einer bestimmten Startposition ersetzen, siehe REPLACE().) Sie suchen nach Beispielen dafür, wie Sie SUBSTITUTE() nutzen können? Werfen Sie einen Blick auf diesen Blogbeitrag mit sieben zeitsparenden Austauschformeln.	`SUBSTITUTE("gold mold", "old", "et")` => get met `SUBSTITUTE("gold mold", "old", "et", 1)` => get mold
`T(value1)`	Gibt das Argument zurück, wenn es sich um Text handelt, und sonst ein leeres Ergebnis.	`T("text only")` => text only `T(42)` => blank
`TRIM(string)`	Entfernt Leerzeichen am Anfang und Ende einer Zeichenfolge.	`TRIM(" Hello! ")` => Hello!
`UPPER(string)`	Ändert eine Zeichenfolge in Großschreibung.	`UPPER("Hello!")` => HELLO!

Logikoperatoren und -funktionen

Um die folgenden Textfunktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „❓ Beispiele für logische Funktionen“ in der Formel-Experimentier-Base an.

Logikoperatoren

Operator	Beschreibung	Beispiele
`>`	Größer als	`3 > 2` => TRUE
`<`	Kleiner als	`2 < 3` => TRUE
`>=`	Größer als oder gleich	`3 >= 3` => TRUE
`<=`	Kleiner als oder gleich	`2 <= 2` => TRUE
`=`	Gleich	`2 = 2` => TRUE
`!=`	Ungleich	`3 != 2` => TRUE

Logikfunktionen

Funktion	Beschreibung	Beispiele
`AND(expression, [expression, ...])`	Gibt true/wahr zurück, wenn alle Argumente wahr sind, und ansonsten false/falsch.	`AND({Field 1}, {Field 2})` => 1 (if both field values are truthy)
`BLANK()`	Gibt einen leeren Wert zurück.	`IF({Price} > 1000000, "Wow, that's pretty expensive", BLANK())`
`ERROR()`	Gibt einen Fehlerwert zurück.	`IF({Price} < 0, ERROR(), "More than zero!")`
`FALSE()`	Logikwert falsch. Falsch wird numerisch als 0 dargestellt.	`IF(2 = 3, TRUE(), FALSE())` => 0
`IF(expression, value1, value2)`	Gibt value1 zurück, wenn der logische Ausdruck true/wahr ist, und sonst value2. Kann auch verwendet werden, um verschachtelte IF-Anweisungen zu erstellen. Kann auch verwendet werden, um zu prüfen, ob eine Zelle leer ist.	`IF({Sales} > 50, "Win", "Lose")` `IF({WaterTemp} > 100, IF({WaterTemp }< 212, "just right", "too hot"), "too cold")` `IF({Due Date} = BLANK(), "Please enter date", "Date entered")`
`ISERROR(expr)`	Gibt true/wahr zurück, wenn der Ausdruck einen Fehler verursacht.	`ISERROR(2/0)` => 1 (true because of the "divide by zero" error)
`NOT(expression)`	Kehrt den logischen Wert seines Arguments um.	`NOT({Total} = 0)`
`OR(expression, [exp2, ...])`	Gibt true/wahr zurück, wenn eines der Argumente wahr ist.	`OR({Field 1}, {Field 2})` => 1 (if one field value is truthy)
`SWITCH(expression, [pattern, result ... , default])`	Verwendet einen Ausdruck, eine Liste möglicher Werte für diesen Ausdruck und für jeden einen Wert, den der Ausdruck in diesem Fall annehmen soll. Kann auch einen Standardwert verwenden, wenn der eingegebene Ausdruck zu keinem der definierten Muster passt. In vielen Fällen kann SWITCH() statt einer verschachtelten IF-Formel verwendet werden.	`Example 1: SWITCH({Status}, "To Do", "Get this started!", "In Progress", {Due Date}, "Done", "Work complete!" )` => if the {Status} field is the value "To Do" then this would return "Get this started!" `SWITCH( 1, 1, "one", 2, "two", "many") => one`
`TRUE()`	Logikwert wahr. Der Wahrheitswert wird numerisch durch eine 1 dargestellt.	`IF(2 = 2, TRUE(), FALSE())` => 1
`XOR(expression1, [exp2, ...])`	Gibt true/wahr zurück, wenn eine ungerade Zahl an Argumenten wahr ist.	`XOR(TRUE(), FALSE(), TRUE())` => 0 `XOR(TRUE(), FALSE(), FALSE())` => 1

Numerische Operatoren und Funktionen

Um die folgenden numerischen Funktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „#️⃣ Beispiele für numerische Funktionen“ in der Formel-Experimentier-Base an.

Numerische Operatoren

Operator	Beschreibung	Beispiele
`+`	Addiert zwei numerische Werte.	`Size + 2`
`-`	Subtrahiert zwei numerische Werte.	`Price - 3.00`
`*`	Multipliziert zwei numerische Werte.	`Price * Quantity`
`/`	Dividiert zwei numerische Werte.	`Price / {Num People}`

Numerische Funktionen

Funktion	Beschreibung	Beispiele
`ABS(value)`	Gibt den absoluten Wert zurück.	`ABS(-5)` => 5
`AVERAGE(number1, [number2, ...])`	Gibt den Durchschnitt der Zahlen zurück.	`AVERAGE(2.3, 5.7, 6.8)` => 3.93
`CEILING(value, [significance])`	Gibt das nächste signifikante Vielfache einer ganzen Zahl zurück, das größer oder gleich dem Wert ist. Wenn keine Signifikanz festgelegt ist, wird eine Signifikanz von 1 angenommen.	`CEILING(1.01)` => 2 `CEILING(1.01, 0.1)` => 1.1
`COUNT(number1, [number2, ....])`	Zählt die Anzahl der numerischen Elemente.	`COUNT(1,2,3,"","four")` => 3
`COUNTA(textOrNumber1, [number2, ....])`	Zählt die Anzahl der nicht leeren Werte. Diese Funktion zählt sowohl numerische als auch Textwerte.	`COUNTA(1,2,3,"","four")` => 4
`COUNTALL(textOrNumber1, [number2, ....])`	Zählt die Anzahl aller Elemente einschließlich Text und Leerzeichen.	`COUNTALL(1,2,3,"","four")` => 5
`EVEN(value)`	Gibt die kleinste gerade ganze Zahl zurück, die größer oder gleich dem angegebenen Wert ist.	`EVEN(2.2)` => 4 `EVEN(-1.6)` => -2
`EXP(power)`	Berechnet Eulersche Zahl (e) hoch festgelegtem X.	`EXP(1)` => 2.71828 `EXP(3)` => 20.08554
`FLOOR(value, [significance])`	Gibt das nächste signifikante Vielfache einer ganzen Zahl zurück, das kleiner oder gleich dem Wert ist. Wenn keine Signifikanz festgelegt ist, wird eine Signifikanz von 1 angenommen.	`FLOOR(1.99)` => 1 `FLOOR(1.99, 0.1)` => 1.9
`INT(value)`	Gibt die größte ganze Zahl zurück, die kleiner oder gleich dem angegebenen Wert ist.	`INT(1.99)` => 1 `INT(-1.99)` => -2
`LOG(number, [base])`	Berechnet den Logarithmus des Werts in der bereitgestellten Base. Ist nichts angegeben, ist der Standardwert für die Base 10.	`LOG(1024, 2)` => 10 `LOG(1000)` => 3
`MAX(number1, [number2, ...])`	Gibt die größte der angegebenen Zahlen zurück.	`MAX({Field1}, {Field2})` `MAX(10, 100)` => 100
`MIN(number1, [number2, ...])`	Gibt die kleinste der angegebenen Zahlen zurück.	`MIN({Field1}, Field2})` `MIN(10, 100)` => 10
`MOD(value1, divisor)`	Gibt den Rest nach Division des ersten Arguments durch das zweite zurück.	`MOD({Meters}, 1000)` `MOD(7, 5)` => 2
`ODD(value)`	Rundet positive Werte auf die nächste ungerade Zahl auf und negative Werte auf die nächste ungerade Zahl ab.	`ODD(1.1)` => 3 `ODD(-1.1)` => -3
`POWER(base, power)`	Potenziert die angegebene Base mit dem angegebenen Wert.	`POWER(3, 3)` => 27 `POWER(7, 0)` => 1
`ROUND(value, precision)`	Rundet den Wert auf die Anzahl der angegebenen Dezimalstellen. (Insbesondere rundet ROUND auf die nächste ganze Zahl der angegebenen Dezimalstellen auf, wobei die Grenze durch Aufrunden halber Werte auf positive Unendlichkeit aufgelöst wird.)	`ROUND(3.5, 0)` => 4 `ROUND(3.4, 0)` => 3
`ROUNDDOWN(value, precision)`	Rundet den Wert auf die Anzahl der angegebenen Dezimalstellen, wobei immer abgerundet wird, d. h. auf null. (Sie müssen die Anzahl an Dezimalstellen angeben, weil die Funktion sonst nicht funktioniert.)	`ROUNDDOWN(1.9, 0)` => 1 `ROUNDDOWN(-1.9, 0)` => -1
`ROUNDUP(value, precision)`	Rundet den Wert auf die Anzahl der angegebenen Dezimalstellen, wobei immer aufgerundet wird, d. h. von null weg. (Sie müssen die Anzahl an Dezimalstellen angeben, weil die Funktion sonst nicht funktioniert.)	`ROUNDUP(1.1, 0)` => 2 `ROUNDUP(-1.1, 0)` => -2
`SQRT(value)`	Gibt die Quadratwurzel einer nicht negativen Zahl zurück.	`SQRT(100)` => 10
`SUM(number1, [number2, ...])`	Addiert die Zahlen. Entspricht number1 + number2 + ....	`SUM({Field1}, Field2})` `SUM(1,2,3)` => 6
`VALUE(text)`	Wandelt eine Textzeichenfolge in eine Zahl um. Es gibt eine Reihe von Ausnahmen – wenn eine Zeichenfolge bestimmte mathematische Operatoren enthält (-,%), kann das Ergebnis anders als erwartet ausfallen. In diesen Szenarien empfehlen wir eine Kombination aus VALUE und REGEX_REPLACE, um Werte ohne Stellen aus der Zeichenfolge zu entfernen: `VALUE(REGEX_REPLACE(YOURSTRING, "\\D", ""))`	`VALUE("$1000")` => 1000

Datums- und Zeitfunktionen

Sie suchen nach Beispielen, wie Sie Formeln für Fälligkeitsdaten und Fristen verwenden können? Werfen Sie einen Blick auf diesen Blogbeitrag mit 10 zeitsparenden Datumsformeln.

Um die folgenden Datums- und Uhrzeitfunktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „📆 Beispiele für Datums- und Uhrzeitfunktionen“ in der Formel-Experimentier-Base an.

Funktion	Beschreibung	Beispiele
`CREATED_TIME()`	Gibt das Datum und die Uhrzeit der Datensatzerstellung zurück.	`CREATED_TIME()` => 2015-11-11T22:18:17
`DATEADD([date], [#], 'units')`	Fügt einer Datums-/Zeitangabe angegebene „Anzahl“-Einheiten hinzu. Hier finden Sie die Liste geteilter Einheitenbezeichner. Für diese Funktion empfehlen wir die Verwendung des vollständigen Einheitenbezeichners (d. h. „Jahre“ anstellte von „J“) für die gewünschte Einheit.	`DATEADD("07/10/19", 10, "days")` => 2019-07-20 `DATEADD("07/10/19 01:01:00", 60, "seconds")` => 2019-07-10 1:02am `DATEADD(TODAY(), 20, "days")`
`DATESTR([date])`	Formatiert eine Datums-/Zeitangabe als Zeichenfolge (JJJJ-MM-DD).	`DATESTR("12/13/21")` => 2021-12-13
`DATETIME_DIFF([date1], [date2], 'units')`	Gibt den Unterschied zwischen Datums-/Zeitangaben in angegebenen Einheiten zurück. Der Unterschied zwischen Datums-/Zeitangaben wird durch Subtraktion von [date2] von [date1] bestimmt. Das heißt, dass das Ergebnis negativ ist, wenn [date2] nach [date1] liegt. Die Standardeinheit sind Sekunden. (Hier finden Sie eine Liste der Einheitenbezeichner.) HINWEIS 1: Die Formel `The DATETIME_DIFF()` gibt ganze Zahlen für alle Einheitenbezeichner zurück. HINWEIS 2: Wenn Sie versuchen, `DATETIME_DIFF()` mit statischen Daten oder Daten zu verwenden, die als Zeichenfolge formatiert sind, sollten Sie die Funktion `DATETIME_PARSE()` in Ihre Formel einbetten, um die Zeichenfolge im Airtable Backend in lesbare Daten umzuwandeln.	`DATETIME_DIFF("04/06/2019 12:00", "04/05/2019 11:00", "hours")` => 25 `DATETIME_DIFF("04/06/2019 12:00", "04/05/2019 11:00", "days")` => 1 `DATETIME_DIFF({Date Bought}, {Date Sold}, 'minutes')` => 30
`DATETIME_FORMAT([date], '[specified output format]')`	Formatiert eine Datums-/Zeitangabe als angegebene Zeichenfolge. Für eine Erklärung, wie Sie diese Funktion mit Datumsfeldern verwenden, klicken Sie hier. Hier finden Sie eine Liste der unterstützten Formatbezeichner.	`DATETIME_FORMAT("07/10/19", "YYYY")` => 2019 `DATETIME_FORMAT("07/10/19", "DD YYYY")` => 10 2019
`DATETIME_PARSE(date, ['input format'], ['locale'])`	Interpretiert eine Textzeichenfolge als strukturiertes Datum mit optionalem Eingabeformat und Gebietsschemaparametern. Das Ausgabeformat wird immer als „M/T/JJJJ h:mm a“ formatiert.	`DATETIME_PARSE("4 Mar 2017 23:00", 'D MMM YYYY HH:mm')` => 3/4/2017 11:00pm
`DAY([date])`	Gibt den Tag des Monats einer Datums-/Zeitangabe in Form einer Zahl zwischen 1 und 31 zurück.	`DAY("02/17/2013")` => 17
`HOUR([datetime])`	Gibt die Stunde einer Datums-/Zeitangabe als Zahl zwischen 0 (00:00 Uhr) und 23 (23:00 Uhr) zurück.	`HOUR("4 Mar 2017 7:00")` => 7
`IS_AFTER([date1], [date2])`	Bestimmt, ob [date1] später als [date2] liegt. Gibt bei Ja 1 und bei Nein 0 zurück.	`IS_AFTER("1/1/1979", "1/1/2000")` => 0 `IS_AFTER({Deadline}, TODAY())`
`IS_BEFORE([date1], [date2])`	Bestimmt, ob [date1] früher als [date2] liegt. Gibt bei Ja 1 und bei Nein 0 zurück.	`IS_BEFORE("1/1/1979", "1/1/2000")` => 1 `IS_BEFORE({Deadline}, TODAY())`
`IS_SAME([date1], [date2], [unit])`	Vergleicht zwei Daten bis zu einem Wert und legt fest, ob sie identisch sind. Gibt bei Ja 1 und bei Nein 0 zurück.	`IS_SAME("1/1/1979", "1/1/1979")` => 1 `IS_SAME({Date 1}, {Date 2}, 'hour')` => 0
`LAST_MODIFIED_TIME([{field1},{field2}, ...])`	Gibt das Datum und die Uhrzeit der letzten Änderung zurück, die eine Benutzerin in einem nicht berechneten Feld der Tabelle vorgenommen hat. Wenn für Sie nur Änderungen spezifischer Felder von Belang sind, können Sie einen oder mehrere Feldnamen eingeben. Die Funktion gibt dann nur das Datum und die Uhrzeit der letzten Änderung an den angegebenen Feldern zurück.	`LAST_MODIFIED_TIME()` => 5/9/2019 1:27 a.m. `LAST_MODIFIED_TIME({Due Date})` => 3/16/2019 6:45 p.m.
`MINUTE([datetime])`	Gibt die Minute einer Datums-/Zeitangabe als ganze Zahl zwischen 0 und 59 zurück.	`MINUTE("02/17/2013 7:31")` => 31
`MONTH([date])`	Gibt den Monat einer Datums-/Zeitangabe als ganze Zahl zwischen 1 (Januar) und 12 (Dezember) zurück.	`MONTH("02/17/2013 7:31")` => 2
`NOW()`	Trotz der Ähnlichkeit mit der Funktion TODAY() gibt NOW() das aktuelle Datum UND die Uhrzeit zurück. Diese Formel wird aktualisiert, wenn die Formel neu berechnet oder eine Base geladen wird oder aber alle 15 Minuten, wenn eine Base geöffnet ist. Wenn die Base geschlossen ist, wird sie etwa jede Stunde aktualisiert; jedoch nur, wenn die Base zeitabhängige Automatisierungstrigger oder -aktionen oder Sync-Abhängigkeiten hat.	Das folgende Beispiel illustriert die Rückgabe bei gleichzeitiger Eingabe von NOW() und TODAY() im Format „08/06/2020 8:03am“ als GMT im 12-Stunden-Format: Die Zeitformatierung (GMT/Ortszeit, 12/24 Stunden) können Sie auf der Registerkarte „Formatierung“ ändern. `NOW()` => 08/06/2020 8:03am `TODAY()` => 08/06/2020 12:03am
`SECOND([datetime])`	Gibt die Sekunde einer Datums-/Zeitangabe als ganze Zahl zwischen 0 und 59 zurück.	`SECOND("02/17/2013 7:31:25")` => 25
`SET_LOCALE([date], [locale_modifier])`	Legt ein bestimmtes Gebietsschema für eine Datums-/Zeitangabe fest. Muss zusammen mit DATETIME_FORMAT verwendet werden. Hier finden Sie eine Liste der unterstützten Gebietsschemamodifikatoren.	`DATETIME_FORMAT(SET_LOCALE("07/10/19 ", 'es'), 'LLLL')` => miércoles, 10 de julio de 2019 0:00
`SET_TIMEZONE([date], [tz_identifier])`	Legt die Zeitzone für eine Datums-/Zeitangabe fest. Muss zusammen mit DATETIME_FORMAT verwendet werden. Hier finden Sie eine Liste der unterstützten Zeitzonenbezeichner.	`DATETIME_FORMAT(SET_TIMEZONE("07/10/19 13:00", 'Australia/Sydney'), 'M/D/YYYY h:mm')` => 7/10/2019 11:00
`TIMESTR([date/timestamp])`	Formatiert eine Zeit-/Datumsangabe als Nur-Zeit-Zeichenfolge (hh:mm:ss).	`TIMESTR("02/17/2013 7:31:25")` => 7:31:25
`TONOW([date]) & FROMNOW([date])`	Berechnet die Anzahl an Tagen zwischen dem aktuellen Datum und einem anderen Datum.	`TONOW({Date})` => 25 days `FROMNOW({Date})` => 25 days
`TODAY()`	Trotz der Ähnlichkeit mit der Funktion NOW() gibt TODAY() das aktuelle Datum zurück (und nicht die aktuelle Zeit – sofern formatiert, wird die Zeit als 12:00am zurückgegeben). Diese Formel wird aktualisiert, wenn die Formel neu berechnet oder eine Base geladen wird oder aber alle 15 Minuten, wenn eine Base geöffnet ist. Wenn die Base geschlossen ist, wird sie etwa jede Stunde aktualisiert; jedoch nur, wenn die Base zeitabhängige Automatisierungstrigger oder -aktionen oder Sync-Abhängigkeiten hat.	Das folgende Beispiel illustriert die Rückgabe bei gleichzeitiger Eingabe von NOW() und TODAY() im Format „08/06/2020 8:03am“ als GMT im 12-Stunden-Format: Die Zeitformatierung (GMT/Ortszeit, 12/24 Stunden) können Sie auf der Registerkarte „Formatierung“ ändern. `NOW()` => 08/06/2020 8:03am `TODAY()` => 08/06/2020 12:03am
`WEEKDAY(date, [startDayOfWeek])`	Gibt den Wochentag als ganze Zahl zwischen einschließlich 0 und 6 wieder. Sie können optional ein zweites Argument angeben (entweder „Sonntag“ oder „Montag“), um die Woche an diesem Datum beginnen zu lassen. Wenn nicht, beginnen Wochen am Sonntag. Beispiel: WEEKDAY(TODAY(), „Montag“)	`WEEKDAY("2021-06-09")` => 3 (for Wednesday)
`WEEKNUM(date, [startDayOfWeek])`	Gibt die Kalenderwoche eines Jahres zurück. Sie können optional ein zweites Argument angeben (entweder „Sonntag“ oder „Montag“), um die Woche an diesem Datum beginnen zu lassen. Wenn nicht, beginnen Wochen am Sonntag. Beispiel: `WEEKNUM(TODAY(), "Monday")`	`WEEKNUM("02/17/2013") => 8`
`WORKDAY(startDate, numDays, [holidays])`	Gibt ein Datum als numDays Werktage nach startDate zurück. Werktage umfassen weder Wochenenden noch optionale Listen von Feiertagen und werden als durch Trennzeichen getrennte Zeichenfolge des nach ISO formatierten Datums formatiert.	`WORKDAY('10/16/20', 10, '2020-10-16, 2020-10-19')` => 2020-11-02 `WORKDAY({Launch date}, 100)`
`WORKDAY_DIFF(startDate, endDate, [holidays])`	Zählt die Anzahl an Werktagen zwischen startDate und endDate. Werktage umfassen weder Wochenenden noch optionale Listen von Feiertagen und werden als durch Trennzeichen getrennte Zeichenfolge des nach ISO formatierten Datums formatiert.	`WORKDAY_DIFF('10/16/20','11/02/2020', '2020-10-16, 2020-10-19')` => 10 `WORKDAY_DIFF({Assignment date}, {Due Date}, {Holidays})`
`YEAR([date])`	Gibt das vierstellige Jahr einer Datums-/Zeitangabe zurück.	`YEAR("2021-06-09")` => 2021

Array-Funktionen

Hinweis: Array-Funktionen können nur in Rollup-Feldern verwendet werden oder wenn das Eingabefeld ein Lookup-Feld ist.

Um die folgenden Array-Funktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „[] Beispiele für Array-Funktionen“ in der Formel-Experimentier-Base.

Funktion	Beschreibung	Beispiele
`ARRAYCOMPACT(values)`	Entfernt leere Zeichenfolgen und Nullwerte aus dem Array. Behält false/falsch-Werte und Zeichenfolgen bei, die eines oder mehrere Leerzeichen enthalten.	values = [1,2,3,"",null,false," "] `ARRAYCOMPACT(values)` => [1,2,3,false," "]
`ARRAYFLATTEN(values)`	Vereinfacht das Array durch Entfernung eingebetteter Arrays. Alle Elemente werden Elemente eines einzigen Arrays.	values = [[1,2,"",3],[false]] `ARRAYFLATTEN(values)` => [1,2,3,false]
`ARRAYJOIN(values, separator)`	Verbindet ein Array aus Rollup-Elementen zu einer Zeichenfolge mit Trennzeichen.	values = [1,2,3] `ARRAYJOIN(values, "; ")` => "1; 2; 3"
`ARRAYUNIQUE(values)`	Gibt nur eindeutige Elemente im Array zurück.	values = [1,2,3,3,2,1] `ARRAYUNIQUE(values)` => [1,2,3]

Datensatzfunktionen

Um die folgenden Datensatzfunktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „✍️ Beispiele für Datensatzfunktionen“ in der Formel-Experimentier-Base an.

Funktion	Beschreibung	Beispiele
`CREATED_TIME()`	Gibt die Erstellungszeit des aktuellen Datensatzes zurück.	`"Created on " & CREATED_TIME()`
`LAST_MODIFIED_TIME()`	Gibt das Datum und die Uhrzeit der letzten Änderung zurück, die eine Benutzerin in einem nicht berechneten Feld der Tabelle vorgenommen hat. Wenn für Sie nur Änderungen spezifischer Felder von Belang sind, können Sie einen oder mehrere Feldnamen eingeben. Die Funktion gibt dann nur das Datum und die Uhrzeit der letzten Änderung an den angegebenen Feldern zurück.	`"Last modified on " & LAST_MODIFIED_TIME()`
`RECORD_ID()`	Gibt die ID des aktuellen Datensatzes zurück.	`"https://awesomeservice.com/view?recordId=" & RECORD_ID()`

REGEX-Funktionen

Mit regulären Ausdrücken (oder REGEX) können Sie Zeichenkombinationen in Textzeichenfolgen abgleichen. Die REGEX-Funktionen von Airtable werden mithilfe der RE2-Bibliothek für reguläre Ausdrücke implementiert. Weitere Informationen zu den REGEX-Funktionen finden Sie in diesem Support-Artikel.

Um die folgenden REGEX-Funktionen in Aktion kennenzulernen und sie selbst auszuprobieren, sehen Sie sich die Tabelle „🔎 Beispiele für REGEX-Funktionen“ in der Formel-Experimentier-Base an.

Funktion	Beschreibung	Beispiele
`REGEX_MATCH(string, regex)`	Gibt zurück, ob der Eingabetext einem REGEX entspricht.	`REGEX_MATCH("Hello World", "Hello.World") => 1`
`REGEX_EXTRACT(string, regex)`	Gibt die erste Teilzeichenfolge zurück, die einem REGEX entspricht.	`REGEX_EXTRACT("Hello World", "W.*") => "World"`
`REGEX_REPLACE(string, regex, replacement)`	Ersetzt alle passenden Teilzeichenfolgen durch den Wert der Ersatzzeichenfolge.	`REGEX_REPLACE("Hello World", " W.*", "") => "Hello"`

War dieser Artikel hilfreich?

What's Next

Airtable formula field overview

Inhaltsverzeichnis

 Einführung
Ausdrücke
Textoperatoren und -funktionen
Logikoperatoren und -funktionen
Numerische Operatoren und Funktionen
Datums- und Zeitfunktionen
Array-Funktionen
Datensatzfunktionen
REGEX-Funktionen