Referencia al campo de fórmula
  • 22 Dec 2023
  • 16 Minutos para leer
  • Oscuro
    Ligero
  • PDF

Referencia al campo de fórmula

  • Oscuro
    Ligero
  • PDF

Article Summary

Las fórmulas pueden incluir funciones, operaciones numéricas, operaciones lógicas y operaciones de texto que actúan sobre los campos. Para obtener una descripción general de los campos de fórmula, consulta la Guía de campos de fórmula, búsqueda, recuento y compilación.

Introducción

Disponibilidad en planTodos los tipos de plan
PlataformasWeb/navegador, app de Mac y app de Windows
Pruébalo en Airtable

Añadir un campo de fórmula 

 

En una fórmula, puede hacer referencia a campos (columnas) por su nombre. Para devolver el valor de un campo existente, simplemente tienes que introducir el nombre de ese campo:

Price

Por ejemplo, si quisieras una fórmula que calculara un total basado en los campos de precio y cantidad, sería algo así:

Price * Quantity

Los nombres de campos con varias palabras deben ir entre corchetes:

MIN({Regular Price}, {Sale Price})

Las fórmulas pueden incluir paréntesis () para cambiar el orden de las operaciones:

(Apples + Oranges) / Guests

Expresiones

Una expresión se crea cuando se combinan valores, campos o fórmulas y esa combinación se evalúa a un único valor. Se pueden crear expresiones sencillas, como en el siguiente ejemplo (la fórmula devolvería un único valor, por lo que es una expresión):

{Sales Tax} * {Price}

También se pueden encadenar expresiones, lo que resulta especialmente útil cuando se utilizan operadores lógicos. Por ejemplo, el patrón técnico para la fórmula IF() es IF(expression, value1, value2).  Si profundizamos un poco más en el ejemplo anterior, digamos que queremos saber cuándo el precio total de nuestro artículo es superior a 100:

IF(   {Sales Tax} * {Price} > 100,   "This is over 100",   "This is less than 100" )

La expresión en el bloque anterior es {Sales Tax} * {Price} > 100.

Tus expresiones pueden ser tan complicadas como quieras o necesites. ¿Quieres experimentar con las expresiones y aprender más sobre ellas? ¿O sobre las fórmulas en general?

Hemos creado la siguiente base Zona de Juegos con Fórmulas como un espacio para consultar y probar cualquiera de las fórmulas que se muestran a continuación. Como el nombre de la base lo indica, creamos esta experiencia de base Zona de Juegos con Fórmulas con la idea de "jugar" para que puedas aprender y probar fórmulas de manera más práctica. Te recomendamos crear una copia personal de la siguiente base Zona de Juegos con Fórmulas para que puedas consultarla fácilmente cuando quieras. 

 Última actualización: 21/9/2021

Si es la primera vez que abres esta base, mira este rápido video de demostración para hacerte una idea general de cómo está estructurada.

Operadores y funciones de texto

Para ver las siguientes funciones de texto en acción y probarlas por tu cuenta, consulta la tabla ✏️ Ejemplos de funciones de texto en la Zona de Juegos con Fórmulas

Operadores de texto

OperadorDescripciónEjemplos
&

Concatena valores de texto en un único valor de texto.

Para concatenar texto estático, colócalo entre comillas dobles. Para concatenar comillas dobles, debes usar una barra invertida (\) como carácter de escape.

Equivale a CONCATENATE().

Name & " - " & Age

=> Jane - 28

"\""&{Product Name}&"\""

=> "GreatProduct"

Funciones de texto

FunciónDescripciónEjemplos
ARRAYJOIN([item1, item2, item3], separator)

Une la cadena de elementos en una cadena de texto con un separador.

ARRAYJOIN(values, "; ") 

=> 1; 2; 3

CONCATENATE(text1, [text2, ...])

Une los argumentos de texto en un único valor de texto.

Para concatenar texto estático, colócalo entre comillas dobles. Para concatenar comillas dobles, debes usar una barra invertida (\) como carácter de escape.

Equivale al uso del operador Y.

CONCATENATE("Bob"," - ", 43)

=> Bob - 43

CONCATENATE("\"",{Name},"\"")

=> "Bob"

ENCODE_URL_COMPONENT(component_string)

Sustituye determinados caracteres por equivalentes codificados para su uso al crear URL o URI. No codifica los siguientes caracteres: - _ . ~

ENCODE_URL_COMPONENT("chicken & waffles")

=> chicken%20%26%20waffles

FIND(stringToFind, whereToSearch,[startFromPosition])

Busca una instancia de stringToFind en la cadena de texto whereToSearch a partir de una startFromPosition opcional. (De forma predeterminada, startFromPosition es 0). Si no se encuentra ninguna instancia de stringToFind, el resultado será 0.

Igual que SEARCH(), aunque SEARCH() devuelve un valor vacío en lugar de 0 si no se encuentra ninguna instancia de stringToFind.

FIND("fox", "quick brown fox")

=> 13

LEFT(string, howMany)

Extrae los caracteres howMany del principio de la cadena de texto.

LEFT("quick brown fox", 5)

=> quick

LEN(string)

Devuelve la longitud de una cadena de texto.

LEN("quick brown fox")

=> 15

LOWER(string)

Hace que una cadena de texto aparezca en minúsculas.

LOWER("Hello!")

=> hello!

MID(string, whereToStart, count)

Extrae una subcadena de caracteres de recuento a partir de whereToStart.

MID("quick brown fox", 6, 5)

=> brown

REPLACE(string, start_character, number_of_characters, replacement)

Sustituye el número de caracteres que empiezan por el carácter inicial por el texto de sustitución.

(Si quieres una forma de buscar y sustituir todas las instancias de old_text por new_text, consulta SUBSTITUTE()).

REPLACE("database", 2, 5, "o")

=> dose

REPT(string, number)

Repite la cadena de texto el número de veces especificado.

REPT("Hi! ", 3)

=> Hi! Hi! Hi!

RIGHT(string, howMany)

Extrae los caracteres howMany del final de la cadena de texto.

RIGHT("quick brown fox", 5)

=> n fox

SEARCH(stringToFind, whereToSearch,[startFromPosition])

Busca una instancia de stringToFind en la cadena de texto whereToSearch a partir de una startFromPosition opcional. (De forma predeterminada, startFromPosition es 0). Si no se encuentra ninguna instancia de stringToFind, el resultado estará vacío.

Igual que FIND(), aunque FIND() devuelve 0 en lugar de un valor vacío si no se encuentra ninguna instancia de stringToFind.

SEARCH("World", "Hello World")

=> 7

SUBSTITUTE(string, old_text, new_text, [index])

Sustituye las instancias de old_text por new_text.

Opcionalmente, se puede especificar un número de índice (a partir de ) para reemplazar solo una instancia específica de old_text. Si no se especifica ningún número de índice, se reemplazarán todas las instancias de old_text.

(Si buscas una forma de sustituir caracteres de una cadena de texto a partir de un punto de inicio especificado, consulta REPLACE()).

¿Buscas ejemplos de cómo usar SUBSTITUTE()? Consulta esta entrada del blog sobre 7 fórmulas de sustitución que te ahorrarán tiempo.

SUBSTITUTE("gold mold", "old", "et")

=> get met

SUBSTITUTE("gold mold", "old", "et", 1)

=> get mold

T(value1)

Devuelve el argumento si es texto y en blanco en caso contrario.

T("text only")

=> text only

T(42)

=> blank

TRIM(string)

Elimina los espacios en blanco al principio y al final de la cadena de texto.

TRIM(" Hello! ")

=> Hello!

UPPER(string)

Hace que una cadena de texto aparezca en mayúsculas.

UPPER("Hello!")

=> HELLO!

Operadores y funciones lógicos

Para ver las siguientes funciones lógicas en acción y probarlas por tu cuenta, consulta la tabla❓Ejemplos de funciones lógicas en la Zona de Juegos con Fórmulas

Operadores lógicos

OperadorDescripciónEjemplos

Mayor que

3 > 2

=> TRUE

Menor que

2 < 3

=> TRUE

>=

Mayor o igual que

3 >= 3

=> TRUE

<=

Menor o igual que

2 <= 2

=> TRUE

=

Igual que

2 = 2

=> TRUE

!=

No es igual que

3 != 2

=> TRUE

Funciones lógicas

FunciónDescripciónEjemplos
AND(expression, [expression, ...])

Devuelve verdadero si todos los argumentos son verdaderos; en caso contrario, devuelve falso.

AND({Field 1}, {Field 2})

=> 1 (if both field values are truthy)

BLANK()

Devuelve un valor en blanco.

IF({Price} > 1000000, "Wow, that's pretty expensive", BLANK())
ERROR()

Devuelve el valor de error.

IF({Price} < 0, ERROR(), "More than zero!")
FALSE()

Valor lógico falso. Falso se representa numéricamente con un 0.

IF(2 = 3, TRUE(), FALSE())

=> 0 

IF(expression, value1, value2)

Devuelve value1 si la expresión lógica es verdadera; en caso contrario, devuelve value2. También se puede usar para hacer frases condicionales de tipo SI anidadas.

Además, se puede usar para comprobar si una celda está en blanco o vacía.

IF({Sales} > 50, "Win", "Lose")

 

IF({WaterTemp} > 100, IF({WaterTemp }< 212, "just right", "too hot"), "too cold")

 

IF({Due Date} = BLANK(), "Please enter date", "Date entered")
ISERROR(expr)

Devuelve verdadero si la expresión provoca un error.

ISERROR(2/0)

=> 1 (true because of  the "divide by zero" error)

NOT(expression)

Invierte el valor lógico de su argumento.

NOT({Total} = 0)
OR(expression, [exp2, ...])

Devuelve verdadero si alguno de los argumentos es verdadero.

OR({Field 1}, {Field 2})
=> 1 (if one field value is truthy)
SWITCH(expression, [pattern, result ... , default])

Toma una expresión, una lista de posibles valores para esa expresión y, para cada uno de ellos, un valor que la expresión debería tomar en ese caso. También puede tomar un valor predeterminado si la entrada de la expresión no coincide con ninguno de los patrones definidos. En muchos casos, se puede usar SWITCH() en lugar de una fórmula SI anidada.

Example 1:  SWITCH({Status},
 "To Do", "Get this started!",
 "In Progress", {Due Date},
 "Done", "Work complete!"
 )

=> if the {Status} field is the value "To Do" then this would return "Get this started!"

SWITCH( 1, 

1, "one",

2, "two",

"many")

=> one

TRUE()

Valor lógico verdadero. El valor de verdadero se representa numéricamente con un 1.

IF(2 = 2, TRUE(), FALSE())

=> 1 

XOR(expression1, [exp2, ...])

Devuelve verdadero si un número impar de argumentos es verdadero.

XOR(TRUE(), FALSE(), TRUE())

=> 0

 


XOR(TRUE(), FALSE(), FALSE())

=> 1

Operadores y funciones numéricos

Para ver las siguientes funciones numéricas en acción y probarlas por tu cuenta, consulta la tabla #️⃣ Ejemplos de funciones numéricas en la Zona de Juegos con Fórmulas

Operadores numéricos

OperadorDescripciónEjemplos
+

Suma de dos valores numéricos

Size + 2
-

Resta de dos valores numéricos

Price - 3.00
*

Multiplicación de dos valores numéricos

Price * Quantity 
/

División de dos valores numéricos

Price / {Num People}

Funciones numéricas

FunciónDescripciónEjemplos
ABS(value)

Devuelve el valor absoluto.

ABS(-5)

=> 5

AVERAGE(number1, [number2, ...])

Devuelve el promedio de los números.

AVERAGE(2.3, 5.7, 6.8)

=> 3.93

CEILING(value, [significance])

Devuelve el múltiplo entero de importancia más cercano que sea mayor o igual que el valor. Si no se indica la importancia, se asume una importancia de 1.

CEILING(1.01)

=> 2

CEILING(1.01, 0.1)

=> 1.1

COUNT(number1, [number2, ....])

Cuenta el número de elementos numéricos.

COUNT(1,2,3,"","four")

=> 3

COUNTA(textOrNumber1, [number2, ....])

Cuenta el número de valores no vacíos. Esta función cuenta tanto valores numéricos como de texto.

COUNTA(1,2,3,"","four")

=> 4

COUNTALL(textOrNumber1, [number2, ....])

Cuenta el número de todos los elementos, incluidos el texto y los espacios en blanco.

COUNTALL(1,2,3,"","four")

=> 5

EVEN(value)

Devuelve el número entero par más pequeño que sea mayor o igual que el valor especificado.

EVEN(2.2)

=> 4

EVEN(-1.6)

=> -2

EXP(power)

Calcula el número de Euler (e) hasta la potencia especificada.

EXP(1)

=> 2.71828

EXP(3)

=> 20.08554

FLOOR(value, [significance])

Devuelve el múltiplo entero de importancia más cercano que sea menor o igual que el valor. Si no se indica la importancia, se asume una importancia de 1.

FLOOR(1.99)

=> 1

FLOOR(1.99, 0.1)

=> 1.9

INT(value)

Devuelve el número entero más grande que sea menor o igual que el valor especificado.

INT(1.99)

=> 1

INT(-1.99)

=> -2

LOG(number, [base])

Calcula el logaritmo del valor en la base proporcionada. Si no se especifica, la base predeterminada es 10.

LOG(1024, 2)

=> 10

LOG(1000)

=> 3

MAX(number1, [number2, ...])

Devuelve el mayor de los números dados.

MAX({Field1}, {Field2})

 

MAX(10, 100)

=> 100

MIN(number1, [number2, ...])

Devuelve el menor de los números dados.

MIN({Field1}, Field2})

 

MIN(10, 100)

=> 10

MOD(value1, divisor)

Devuelve el resto después de dividir el primer argumento por el segundo.

MOD({Meters}, 1000)

 

MOD(7, 5)

=> 2

ODD(value)

Redondea el valor positivo aumentando hasta el número impar más próximo y el valor negativo disminuyendo hasta el número impar más próximo.

ODD(1.1)

=> 3

ODD(-1.1)

=> -3

POWER(base, power)

Calcula la base especificada a la potencia especificada.

POWER(3, 3)

=> 27

POWER(7, 0)

=> 1

ROUND(value, precision)

Redondea el valor al número de decimales dado por "precisión". (Específicamente, ROUND redondeará al entero más cercano a la precisión especificada, con empates divididos redondeando la mitad hacia arriba al infinito positivo).

ROUND(3.5, 0)

=> 4

ROUND(3.4, 0)

=> 3

ROUNDDOWN(value, precision)

Redondea el valor al número de decimales dado por "precisión", redondeando siempre hacia abajo, es decir, hacia cero. (Debes dar un valor para la precisión, sino la función no funcionará).

ROUNDDOWN(1.9, 0)

=> 1

ROUNDDOWN(-1.9, 0)

=> -1

ROUNDUP(value, precision)

Redondea el valor al número de decimales dado por "precisión", redondeando siempre hacia arriba, es decir, lejos del cero. (Debes dar un valor para la precisión, sino la función no funcionará).

ROUNDUP(1.1, 0)

=> 2

ROUNDUP(-1.1, 0)

=> -2

SQRT(value)

Devuelve la raíz cuadrada de un número no negativo.

SQRT(100)

=> 10

SUM(number1, [number2, ...])

Suma los números. Equivale a number1 + number2 + ...

SUM({Field1}, Field2})

 

SUM(1,2,3)

=> 6

VALUE(text)

Convierte la cadena de texto en un número.

Existen algunas excepciones: si la cadena de texto contiene determinados operadores matemáticos (-,%), es posible que el resultado no sea el esperado. En estos casos, se recomienda usar una combinación de VALUE y REGEX_REPLACE para eliminar los valores no numéricos de la cadena de texto:

VALUE(REGEX_REPLACE(YOURSTRING, "\\D", ""))
VALUE("$1000")

=> 1000

Funciones de fecha y hora

¿Buscas algunos ejemplos de cómo puedes usar fórmulas con fechas de vencimiento y fechas límite? Consulta esta entrada del blog sobre 10 fórmulas de fechas que te ahorrarán tiempo.

Para ver las siguientes funciones de fecha y hora en acción y probarlas por tu cuenta, consulta la tabla 📆 Ejemplos de funciones de fecha y hora en la Zona de Juegos con Fórmulas

FunciónDescripciónEjemplos
CREATED_TIME()

Devuelve la fecha y hora de creación de un registro determinado. 

CREATED_TIME()

=> 2015-11-11T22:18:17 

DATEADD([date], [#], 'units')

Añade las unidades "count" especificadas a una fecha y hora. Consulta la lista de especificadores de unidades compartidos aquí. Para esta función, recomendamos usar el especificador de unidad completo, (es decir, usar "años" en lugar de "a"), para la unidad deseada. 

DATEADD("07/10/19", 10, "days")

=> 2019-07-20

 

DATEADD("07/10/19 01:01:00", 60, "seconds")

=> 2019-07-10 1:02am

 

DATEADD(TODAY(), 20, "days")
DATESTR([date])

Formatea una fecha y hora en una cadena de texto (AAAA-MM-DD). 

DATESTR("12/13/21")

=> 2021-12-13

DATETIME_DIFF([date1], [date2], 'units')

Devuelve la diferencia entre fechas y horas en las unidades especificadas. La diferencia entre fechas y horas se determina restando [date2] de [date1]. Esto significa que, si [date2] es posterior a [date1], el valor resultante será negativo. 

Las unidades predeterminadas son segundos. (Consulta la lista de especificadores de unidades aquí).

NOTA 1: La fórmula The DATETIME_DIFF()  devolverá enteros para cualquier especificador de unidad. 

NOTA 2: Si intentas usar  DATETIME_DIFF()  con fechas estáticas o formateadas como cadenas de texto, deberás anidar la función DATETIME_PARSE()  en la fórmula para convertir la cadena de texto en una fecha legible en el backend de Airtable. 

 

 

DATETIME_DIFF("04/06/2019 12:00", "04/05/2019 11:00", "hours")

=> 25

 

DATETIME_DIFF("04/06/2019 12:00", "04/05/2019 11:00", "days")

=> 1

 

DATETIME_DIFF({Date Bought}, {Date Sold}, 'minutes')

=> 30

DATETIME_FORMAT([date], '[specified output format]')

Formatea una fecha y hora en una cadena de texto especificada. Para obtener una explicación sobre cómo usar esta función con campos de fecha, haz clic aquí. Consulte una lista de especificadores de formato compatibles.

DATETIME_FORMAT("07/10/19", "YYYY")

=> 2019

 

DATETIME_FORMAT("07/10/19", "DD  YYYY")

=> 10 2019

DATETIME_PARSE(date, ['input format'], ['locale'])

Interpreta una cadena de texto como una fecha estructurada, con parámetros opcionales de formato de entrada y configuración local. El formato de salida siempre será 'M/D/AAAA h:mm a'.

DATETIME_PARSE("4 Mar 2017 23:00", 'D MMM YYYY HH:mm')

=> 3/4/2017 11:00pm 

DAY([date])

Devuelve el día del mes de una fecha y hora como un número entre 1 y 31.

DAY("02/17/2013")

=> 17 

HOUR([datetime])

Devuelve la hora de una fecha y hora como un número entre 0 (12:00 a. m.) y 23 (11:00 p. m.).

HOUR("4 Mar 2017 7:00")

=> 7

IS_AFTER([date1], [date2])

Determina si [date1] es posterior a [date2]. Devuelve 1 en caso afirmativo y 0 en caso negativo.

IS_AFTER("1/1/1979", "1/1/2000")

=> 0

 

IS_AFTER({Deadline}, TODAY())
IS_BEFORE([date1], [date2])

Determina si [date1] es anterior a [date2]. Devuelve 1 en caso afirmativo y 0 en caso negativo.

IS_BEFORE("1/1/1979", "1/1/2000")

=> 1

 

IS_BEFORE({Deadline}, TODAY())
IS_SAME([date1], [date2], [unit])

Compara dos fechas hasta una unidad y determina si son idénticas. Devuelve 1 en caso afirmativo y 0 en caso negativo.

IS_SAME("1/1/1979", "1/1/1979")

=> 1

 

IS_SAME({Date 1}, {Date 2}, 'hour')

=> 0

LAST_MODIFIED_TIME([{field1},{field2}, ...])

Devuelve la fecha y hora de la modificación más reciente que realizó un usuario en un campo no calculado de la tabla. Si solo te interesan los cambios realizados en campos específicos, puedes incluir uno o varios nombres de campo, y la función únicamente devolverá la fecha y hora de la modificación más reciente realizada en cualquiera de los campos especificados.

LAST_MODIFIED_TIME()

=> 5/9/2019 1:27 a.m.

LAST_MODIFIED_TIME({Due Date})

=> 3/16/2019 6:45 p.m.

MINUTE([datetime])

Devuelve el minuto de una fecha y hora como un entero entre 0 y 59.

MINUTE("02/17/2013 7:31")

=> 31  

MONTH([date])

Devuelve el mes de una fecha y hora como un número entre 1 (enero) y 12 (diciembre).

MONTH("02/17/2013 7:31")

=> 2

NOW()

Aunque es similar a la función TODAY(), NOW() devuelve la fecha Y la hora actuales.

Esta función se actualiza cuando se recalcula la fórmula, cuando se carga una base o cada 15 minutos aproximadamente si la base está abierta. Si la base está cerrada, se actualizará aproximadamente cada hora solamente cuando la base tenga desencadenantes o acciones de automatización dependientes del tiempo, o dependencias de sincronización.

Los siguientes ejemplos demuestran el retorno si introdujeras NOW() y TODAY() al mismo tiempo, 8/6/2020 8:03 a. m. formateado como GMT en un reloj de 12 horas:

Puedes cambiar el formato de la hora (GMT/Local, 12/24 horas) en la pestaña de formato.

NOW()

=> 08/06/2020 8:03am

TODAY()

=> 08/06/2020 12:03am

SECOND([datetime])

Devuelve el segundo de una fecha y hora como un entero entre 0 y 59.

SECOND("02/17/2013 7:31:25")

=> 25

SET_LOCALE([date], [locale_modifier])

Establece una configuración local específica para una fecha y hora. Debe usarse junto con DATETIME_FORMAT. Puedes encontrar una lista de modificadores compatibles de configuración local aquí.

DATETIME_FORMAT(SET_LOCALE("07/10/19
 ", 'es'), 'LLLL')

=> miércoles, 10 de julio de 2019 0:00

SET_TIMEZONE([date], [tz_identifier])

Establece una zona horaria específica para una fecha y hora. Debe usarse junto con DATETIME_FORMAT. Puedes encontrar una lista de identificadores de zona horaria compatibles aquí.

DATETIME_FORMAT(SET_TIMEZONE("07/10/19 13:00", 'Australia/Sydney'), 'M/D/YYYY h:mm')

=> 7/10/2019 11:00

TIMESTR([date/timestamp])

Formatea una fecha y hora en una cadena de texto de tiempo solamente (HH:mm:ss).  

TIMESTR("02/17/2013 7:31:25")

=> 7:31:25

TONOW([date]) &  FROMNOW([date])

Calcula el número de días entre la fecha actual y otra fecha.

TONOW({Date})

=> 25 days 

 

FROMNOW({Date})

=> 25 days 

TODAY()

Aunque es similar a la función NOW(), TODAY() devuelve la fecha actual (no la hora actual, si se formatea, la hora devolverá las 12:00 a. m.).

Esta función se actualiza cuando se recalcula la fórmula, cuando se carga una base o cada 15 minutos aproximadamente si la base está abierta. Si la base está cerrada, se actualizará aproximadamente cada hora solamente cuando la base tenga desencadenantes o acciones de automatización dependientes del tiempo, o dependencias de sincronización.

Los siguientes ejemplos demuestran el retorno si introdujeras NOW() y TODAY() al mismo tiempo, 8/6/2020 8:03 a. m. formateado como GMT en un reloj de 12 horas:

Puedes cambiar el formato de la hora (GMT/Local, 12/24 horas) en la pestaña de formato.

NOW()

=> 08/06/2020 8:03am

TODAY()

=> 08/06/2020 12:03am

WEEKDAY(date, [startDayOfWeek])

Devuelve el día de la semana como un número entero entre 0 y 6, incluido.Opcionalmente, se puede proporcionar un segundo argumento (ya sea "domingo" o "lunes") para que las semanas comiencen en ese día. Si se omite, las semanas comienzan en domingo de forma predeterminada. Ejemplo:
 WEEKDAY(TODAY(), "lunes")

WEEKDAY("2021-06-09")

=> 3 (for Wednesday)

WEEKNUM(date, [startDayOfWeek])

Devuelve el número de semana en el año. Opcionalmente, se puede proporcionar un segundo argumento (ya sea "domingo" o "lunes") para que las semanas comiencen en ese día. Si se omite, las semanas comienzan en domingo de forma predeterminada. Ejemplo:

WEEKNUM(TODAY(), "Monday")
WEEKNUM("02/17/2013")  

=> 8

WORKDAY(startDate, numDays, [holidays]) 

Devuelve una fecha que es numDays días laborables después de startDate. Los días laborables excluyen los fines de semana y una lista opcional de días festivos, formateada como una cadena de texto de fechas con formato ISO separadas por comas.

WORKDAY('10/16/20', 10, '2020-10-16, 2020-10-19')

=> 2020-11-02

WORKDAY({Launch date}, 100)
WORKDAY_DIFF(startDate, endDate, [holidays])

Cuenta el número de días laborables entre startDate y endDate. Los días laborables excluyen los fines de semana y una lista opcional de días festivos, formateada como una cadena de texto de fechas con formato ISO separadas por comas.

WORKDAY_DIFF('10/16/20','11/02/2020', '2020-10-16, 2020-10-19')

=> 10

WORKDAY_DIFF({Assignment date}, {Due Date}, {Holidays})
YEAR([date])

Devuelve el año de cuatro dígitos de una fecha y hora.

YEAR("2021-06-09")

=> 2021

Funciones de cadena

Ten en cuenta que las funciones de cadena solo se pueden usar en campos de compilación o cuando el campo de entrada es una búsqueda.

Para ver las siguientes funciones de cadena en acción y probarlas por tu cuenta, consulta la tabla [] Ejemplos de funciones de cadena en la Zona de Juegos con Fórmulas

FunciónDescripciónEjemplos
ARRAYCOMPACT(values)

Elimina las cadenas de texto vacías y los valores nulos de la cadena. Mantiene "falsos" y las cadenas de texto que contienen uno o más caracteres en blanco.

values = [1,2,3,"",null,false," "]

ARRAYCOMPACT(values)

=> [1,2,3,false," "]

ARRAYFLATTEN(values)

Reduce el tamaño de la cadena eliminando cualquier anidamiento. Todos los elementos se convierten en elementos de una única cadena.

values = [[1,2,"",3],[false]]

ARRAYFLATTEN(values)

=> [1,2,3,false]

ARRAYJOIN(values, separator)

Une la cadena de elementos de compilación en una cadena de texto con un separador.

values = [1,2,3]

ARRAYJOIN(values, "; ") 

=> "1; 2; 3"

ARRAYUNIQUE(values)

Solo devuelve los elementos únicos de la cadena.

values = [1,2,3,3,2,1]

ARRAYUNIQUE(values)

=> [1,2,3]

ARRAYSLICE(values, start,[end])


Devuelve un subconjunto de la cadena a partir del primer número de índice, empezando por 1. Opcionalmente, puedes especificar un índice final para detenerlo. Usa números negativos para empezar a contar desde el final de la cadena.

ARRAYSLICE(values, start,[end])

ARRAYSLICE(values, 2, 3) => ["B", "C"] when values are ["A", "B", "C", "D"]

  • Para obtener el primer elemento: ARRAYSLICE(values, 1, 1)
  • Para obtener los primeros dos elementos: ARRAYSLICE(values, 1, 2)
  • Para obtener el último elemento: ARRAYSLICE(values, -1)
  • Para obtener los últimos dos elementos: ARRAYSLICE(values, -2)

Funciones de registro

Para ver las siguientes funciones de registro en acción y probarlas por tu cuenta, consulta la tabla ✍️ Ejemplos de funciones de registro en la Zona de Juegos con Fórmulas

FunciónDescripciónEjemplos
CREATED_TIME()

Devuelve la hora de creación del registro actual.

"Created on " & CREATED_TIME()
LAST_MODIFIED_TIME()

Devuelve la fecha y hora de la modificación más reciente que realizó un usuario en un campo no calculado de la tabla. Si solo te interesan los cambios realizados en campos específicos, puedes incluir uno o varios nombres de campo, y la función únicamente devolverá la fecha y hora de la modificación más reciente realizada en cualquiera de los campos especificados.

"Last modified on " & LAST_MODIFIED_TIME()
RECORD_ID()

Devuelve la ID del registro actual.

"https://awesomeservice.com/view?recordId=" & RECORD_ID()

Funciones REGEX

Las expresiones regulares (o REGEX) se pueden usar para hacer coincidir combinaciones de caracteres dentro de cadenas de texto. Las funciones REGEX de Airtable se implementan mediante la biblioteca de expresiones regulares RE2. Encontrarás más información específica a las funciones REGEX en este artículo de ayuda.

Para ver las siguientes funciones REGEX en acción y probarlas por tu cuenta, consulta la tabla 🔎Ejemplos de funciones de registro en la Zona de Juegos con Fórmulas

FunciónDescripciónEjemplos
REGEX_MATCH(string, regex)

Devuelve si el texto de entrada coincide con una expresión regular.

REGEX_MATCH("Hello World", "Hello.World") => 1
REGEX_EXTRACT(string, regex)

Devuelve la primera subcadena que coincide con una expresión regular.

REGEX_EXTRACT("Hello World", "W.*") => "World"
REGEX_REPLACE(string, regex, replacement)

Sustituye todas las subcadenas que coinciden por un valor de cadena de texto de sustitución.

REGEX_REPLACE("Hello World", " W.*", "") => "Hello" 

¿Te ha sido útil este artículo?